'-----------------------------------------------------
' Renommage en minuscule des fichiers et dossiers
' d'un répertoire 
' Auto-installable (par exécution sans paramètres)
' JC BELLAMY © 2002
'-----------------------------------------------------
Dim shell, args, fso, folder, collfic,curfic
Set args  = Wscript.Arguments
Set shell = WScript.CreateObject("WScript.Shell")
Set fso   = WScript.CreateObject("Scripting.FileSystemObject")
If args.count=0 Then 
' Auto-installation
	Script=Wscript.ScriptFullName
	Key="HKEY_CLASSES_ROOT\Folder\shell\Lowercase\"
	shell.RegWrite Key,"Renommage des fichiers en minuscules"
	Command="cscript """ & Script & """ ""%1"""
	shell.RegWrite Key & "command\",Command
	MsgBox "Script "& Script &" installé", vbInformation, "Renommage de fichiers"
	wscript.quit
	end if
curdir=args(0)
If not fso.FolderExists(curdir)  Then
	wscript.echo "Répertoire inexistant"
	wscript.quit
	End If
set folder=fso.GetFolder(curdir) 
set collfic=folder.Files 
tempname="xxxxx.xxx"
nfic=collfic.count
wscript.echo nfic & " fichiers"
dim fic()
redim fic(nfic+1)
n=0
For each curfic in collfic
	n=n+1
	fic(n)=curfic.Name
	next
If right(curdir,1)<>"\" Then curdir=curdir & "\"

For i = 1 To nfic
	oldname=fic(i)
	set curfic=fso.GetFile(curdir & oldname) 
	newname=lcase(oldname)
	curfic.Name=tempname
	curfic.Name=newname
	wscript.echo i & " : " & oldname & " renommé en " & newname
	Next

MsgBox nfic & " fichiers renommés",,"Renommage en minuscules dans " & Curdir