' ----------------------------------------------------------
' Script de définition d'adresses de serveurs DNS 
'
' JC BELLAMY © 2003
' ----------------------------------------------------------
<job>
<runtime>
<description  author="jcb">
Ce script permet de définir une ou plusieurs adresses IP
de serveurs DNS affectées à une carte réseau donnée.
JCB © 2003
--------------------------------------------------------
</description>
<named name = "card" helpstring = "Nom de la carte (si vide, affichage de la liste des cartes)" type = "string" required = "true" />
<named name = "comp" helpstring = "Nom NetBIOS de l'ordinateur (machine locale par défaut)" type = "string" required = "false" />
<unnamed name = "dns" helpstring = "Adr.IP de serveurs DNS (si vide, affichage de la liste actuelle de DNS)" type = "string" many="true" required = "false" />
<example>
Exemples: 
  setdns.wsf /card:"Intel(R) PRO Adapter" 192.168.0.2 192.168.0.49
	affecte les DNS à la carte
  setdns.wsf /card:"Intel(R) PRO Adapter"
	affiche les DNS actuellement affectés à la carte
  setdns.wsf /card:
	affiche la liste des cartes réseau
  setdns.wsf /card: /comp:BINGERVILLE
	affiche la liste des cartes réseau de l'ordinateur distant
</example>
</runtime>
<script language="VBScript">
Const SW_SHOWNORMAL=1 
Set net   = Wscript.CreateObject("WScript.Network")
Set shell = WScript.CreateObject("WScript.Shell")
Set fso   = WScript.CreateObject("Scripting.FileSystemObject")
Set args  = Wscript.Arguments
nbargs=args.count

If nbargs=0 Then
	WScript.Arguments.ShowUsage
	WScript.Quit
	End If

TestHost false

Set Named   = WScript.Arguments.Named
Set UnNamed = WScript.Arguments.UnNamed

If not named.Exists("card") Then 
	WScript.Arguments.ShowUsage
	WScript.Quit
	End If

If named.Exists("comp") Then
	computer=named.Item("comp")
Else
	computer=net.ComputerName
	End If
computer=uCase(computer)

nbDNS=UnNamed.count
dim DNS ()
on error resume next
msg="Ordinateur " & computer & VBCRLF 
Set objWMI = GetObject("winmgmts:\\" & computer & "\root\cimv2")
If err.number<>0 Then
	msg=msg & "Erreur WMI (" & err.description & ")"
	wscript.echo msg 
	WScript.Quit
	End If
Set colItems = objWMI.ExecQuery("Select * from Win32_NetworkAdapterConfiguration",,48)

curcard=named.Item("card")
If curcard="" Then
	msg=msg & "Liste des cartes réseau :" & VBCRLF
	for each Card in colItems
		msg=msg & VBCRLF
		msg=msg & Card.Description 
		next			
	wscript.echo msg
Else
	for each Card in colItems
		If lcase(Card.Description)=lcase(curcard) Then
			If nbDNS=0 Then
				msg=msg & "Carte " & curcard & VBCRLF
				If IsArray(Card.DNSServerSearchOrder) Then
					min=lbound(Card.DNSServerSearchOrder)
					max=ubound(Card.DNSServerSearchOrder)
					msg=msg & (max-min+1) & " adresses DNS" & VBCRLF 
					For i=min To max
						msg=msg & VBCRLF
						msg=msg & Card.DNSServerSearchOrder(i)
						Next
				else
					msg=msg & Card.DNSServerSearchOrder
					End If	
				wscript.echo msg
			Else
				redim DNS(nbDNS-1)
				For i = 0 To nbDNS-1
					DNS(i)=UnNamed(i)
					Next
				code=Card.SetDNSServerSearchOrder(DNS)
				If code=0 Then
					msg=msg & "DNS affecté(s) à " & curcard & " avec succès"
				Else
					msg=msg & "Erreur d'affectation de DNS à " & curcard & " (code " & code & ")"
					End If
				wscript.echo msg
				End If
			End If
		next
	End If
Wscript.quit
'--------------------------------------------------------------------
'Sous-programme de test du moteur
'Vu les sorties générées, c'est CSCRIPT (et non pas WSCRIPT)
'qui doit être utilisé de préférence
Sub TestHost(force)
dim rep
strappli=lcase(Wscript.ScriptFullName)
strFullName =lcase(WScript.FullName)
i=InStr(1,strFullName,".exe",1)
j=InStrRev(strFullName,"\",i,1)
strCommand=Mid(strFullName,j+1,i-j-1)
if strCommand<>"cscript" then
	If force then 
		Init="Ce script doit être lancé avec CSCRIPT"
	Else
		Init="Il est préférable de lancer ce script avec CSCRIPT"
		End If
	rep=MsgBox(Init & VBCRLF & _
	"Cela peut être rendu permanent avec la commande" & VBCRLF & _
	"cscript //H:CScript //S /Nologo" & VBCRLF & _
	"Voulez-vous que ce soit fait automatiquement?", _
	vbYesNo + vbQuestion,strappli)
	if rep=vbYes  then 
		nomcmd="setscript.bat"
		Set ficcmd = fso.CreateTextFile(nomcmd)
		ficcmd.writeline "@echo off"
		ficcmd.writeline "cscript //H:CScript //S /Nologo"
		ficcmd.writeline "pause"
		params=""
		For i = 0 To nbargs-1 
			params=params & " " & args(i)
			next
		ficcmd.writeline chr(34) & strappli & chr(34) & params
		ficcmd.writeline "pause"
		ficcmd.close
		shell.Run nomcmd, SW_SHOWNORMAL,true
		force=true
		end if
    If force then WScript.Quit
	end if
end sub
'--------------------------------------------------------------------
</script>
</job>